Splošna formula
=ADDRESS(MAX(ROW(rng)),MAX(COLUMN(rng)))
Povzetek
Če želite dobiti naslov zadnje celice v obsegu, lahko uporabite funkcijo ADDRESS skupaj s funkcijami ROW, COLUMN in MAX. V prikazanem primeru je formula v F5:
=ADDRESS(MAX(ROW(data)),MAX(COLUMN(data)))
kjer so podatki imenovani obseg B5: D14.
Pojasnilo
Funkcija ADDRESS ustvari sklic na podlagi dane številke vrstice in stolpca. V tem primeru želimo dobiti zadnjo vrstico in zadnji stolpec, ki ga uporabljajo poimenovani podatki obsega (B5: D14).
Če želite uporabiti zadnjo vrstico, uporabimo funkcijo ROW skupaj s funkcijo MAX, kot je ta:
MAX(ROW(data))
Ker podatki vsebujejo več kot eno vrstico, vrne ROW polje številk vrstic:
(5;6;7;8;9;10;11;12;13;14)
Ta matrika gre neposredno v funkcijo MAX, ki vrne največje število:
MAX((5;6;7;8;9;10;11;12;13;14)) // returns 14
Da dobimo zadnji stolpec, uporabimo funkcijo COLUMN na enak način:
MAX(COLUMN(data))
Ker podatki vsebujejo tri vrstice, vrne COLUMN matriko s tremi številkami stolpcev:
(2,3,4)
in funkcija MAX vrne največje število:
MAX((2,3,4)) // returns 4
Oba rezultata se vrneta neposredno v funkcijo ADDRESS, ki ustvari sklic na celico v vrstici 14, stolpec 4:
=ADDRESS(14,4) // returns $D$14
Če želite relativni naslov namesto absolutne reference, lahko za tretji argument navedete 4:
=ADDRESS(MAX(ROW(data)),MAX(COLUMN(data)),4) // returns D14
Alternativa funkcije CELL
Čeprav to ni očitno, funkcija INDEX vrne referenco, zato lahko s funkcijo CELL z INDEX dobimo naslov zadnje celice v obsegu, kot je ta:
=CELL("address",INDEX(data,ROWS(data),COLUMNS(data)))
V tem primeru s funkcijo INDEX dobimo referenco na zadnjo celico v obsegu, ki jo določimo s posredovanjem skupnih vrstic in skupnih stolpcev za podatke obsega v INDEX. Skupno število vrstic dobimo s funkcijo ROWS in skupno stolpcev s funkcijo COLUMNS:
ROWS(data) // returns 10 COLUMNS(data) // returns 3
Z matriko, ki je na voljo kot podatek, INDEX nato vrne sklic na celico D14:
INDEX(data,10,3) // returns reference to D14
Nato za prikaz naslova uporabimo funkcijo CELL z naslovom.
Opomba: Funkcija CELL je hlapljiva funkcija, ki lahko povzroči težave z zmogljivostjo v velikih ali zapletenih delovnih zvezkih.
