Povzetek
Za izračun skupnega davka od dohodka na podlagi več davčnih razredov lahko uporabite VLOOKUP in tabelo stopenj, strukturirano, kot je prikazano v primeru. Formula v G5 je:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1)
kjer sta "inc" (G4) in "rate" (B5: D11) poimenovana obsega, stolpec D pa je pomožni stolpec, ki izračuna skupni zbrani davek v vsakem oklepaju.
Ozadje in kontekst
Davčni sistem ZDA je "progresiven", kar pomeni, da ljudje z višjim obdavčljivim dohodkom plačujejo višjo zvezno davčno stopnjo. Stopnje se ocenjujejo v oklepajih, opredeljenih z zgornjim in spodnjim pragom. Znesek dohodka, ki spada v dani razred, je obdavčen po ustrezni stopnji za ta razred. Ko se obdavčljivi dohodek povečuje, je dohodek obdavčen v več davčnih razredih. Mnogi davkoplačevalci zato plačujejo več različnih stopenj.
V prikazanem primeru so davčni razredi in stopnje za posamezne vlagatelje datotek v ZDA za davčno leto 2019. Spodnja tabela prikazuje ročne izračune za obdavčljivi dohodek v višini 50.000 USD:
| Nosilec | Izračun | Davek |
|---|---|---|
| 10% | (9.700 USD - 0 USD) x 10% | 970,00 USD |
| 12% | (39.475 USD - 9.700 USD) x 12% | 3.573,00 USD |
| 22% | (50.000–39.475 USD) x 22% | 2.315,50 USD |
| 24% | NA | 0,00 USD |
| 32% | NA | 0,00 USD |
| 35% | NA | 0,00 USD |
| 37% | NA | 0,00 USD |
Skupni davek torej znaša 6.858,50 USD. (prikazano kot 6.859 v prikazanem primeru).
Opombe o namestitvi
1. Ta formula je odvisna od funkcije VLOOKUP v "načinu približnega ujemanja". V načinu približnega ujemanja bo VLOOKUP pregledoval iskalne vrednosti v tabeli (ki jih je treba razvrstiti v naraščajočem vrstnem redu), dokler ne najde višje vrednosti. Potem bo "stopil nazaj" in vrnil vrednost iz prejšnje vrstice. V primeru natančnega ujemanja bo VLOOKUP vrnil rezultate iz ujemajoče se vrstice.
2. Da bi VLOOKUP pridobil dejanske kumulativne zneske davka, so bili ti dodani v tabelo kot pomožni stolpec v stolpcu D. Kopirana formula v D6 je:
=((B6-B5)*C5)+D5
V vsaki vrstici ta formula uporablja stopnjo iz zgornje vrstice za dohodek v tem razredu.
3. Zaradi berljivosti so opredeljeni naslednji imenovani obsegi: "inc" (G4) in "rate" (B5: D11).
Pojasnilo
V G5 je prvi VLOOKUP nastavljen tako, da pridobi kumulativni davek po mejni stopnji s temi vložki:
- Iskalna vrednost je "inc" (G4)
- Iskalna tabela je "stopnje" (B5: D11)
- Številka stolpca je 3, kumulativni davek
- Vrsta ujemanja je 1 = približno ujemanje
VLOOKUP(inc,rates,3,1) // returns 4,543
Z obdavčljivim dohodkom 50.000 USD se VLOOKUP v načinu približnega ujemanja ujema z 39.475 in vrne 4.543, skupni davek pa do 39.475 USD.
Drugi VLOOKUP izračuna preostali dohodek, ki ga je treba obdavčiti:
(inc-VLOOKUP(inc,rates,1,1)) // returns 10,525
izračunano tako:
(50.000-39.475) = 10.525
Končno tretji VLOOKUP dobi (zgornjo) mejno davčno stopnjo:
VLOOKUP(inc,rates,2,1) // returns 22%
To se pomnoži z dohodkom, izračunanim v prejšnjem koraku. Celotna formula je rešena takole:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1) =4,543+(10525)*22% =6,859
Mejne in efektivne stopnje
Celica G6 vsebuje najvišjo mejno stopnjo, izračunano z VLOOKUP:
=VLOOKUP(inc,rates,2,1) // returns 22%
Efektivna davčna stopnja v G7 je skupni davek, deljen z obdavčljivim dohodkom:
=G5/inc // returns 13.7%
Opomba: Na to formulo sem naletel v blogu Jeffa Lenninga na Univerzi Excel. To je odličen primer, kako je mogoče VLOOKUP uporabiti v načinu približnega ujemanja in kako lahko VLOOKUP večkrat uporabimo v isti formuli.
